perm filename IO[CRE,BGB]1 blob
sn#021800 filedate 1973-01-28 generic text, type T, neo UTF8
00100 SUBR(GETFIL)------------------------------------------------------
00200 BEGIN GETFIL;SETUP FILE SPEC FROM TTY LINE - BGB - 10 DEC 72.
00300 SETZM FILNAM↔SETZM EXTION↔SETZM EXTION+1↔SETZM PPPN
00400 OUTSTR[ASCIZ/ FILE = /]
00500 LAC 1,[POINT 6,FILNAM,-1]↔LACI 2,6
00600 INCHWL↔CAIN 15↔GO[INCHWL↔POP2J]↔AOSA(P)
00700 L: INCHWL
00800 CAIN"."↔GO[LAC 1,[POINT 6,EXTION,-1]↔LACI 2,3↔GO L]
00900 CAIN"["↔GO[LAC 1,[POINT 6,PPPN,-1] ↔LACI 2,3↔GO L]
01000 CAIN","↔GO[LAC 1,[POINT 6,PPPN,17] ↔LACI 2,3↔GO L]
01100 CAIN"]"↔GO L
01200 CAIN 15↔GO EOL ;END OF THE LINE.
01300 CAIN 12↔GO EOL
01400 CAIG" "↔GO L ;IGNORE GARBAGE.
01500 SOJL 2,L↔SUBI 40↔IDPB 1↔GO L
01600
01700 EOL: INCHWL
01800 SKIPN 1,EXTION↔LAC 1,ARG2↔DAC 1,EXTION
01900 SKIPN FLGBGB↔POP2J
02000 ;BGB'S DEFAULT PROJECT SPECIFICATION.
02100 SKIPN 1,PPPN↔ LAC 1,ARG1↔DAC 1,PPPN
02200 POP2J
02300 BEND;12/10/72------------------------------------------------------
02400
02500 FILNAM: 0 ;FILE NAME.
02600 EXTION: 0 ;EXTENSION.
02700 0
02800 PPPN: 0 ;PROJECT-PROGRAMMER.
00100 SUBR(TVDSKI)------------------------------------------------------
00200 BEGIN TVDSKI;INPUT TV PICTURE FROM A DISK FILE - BGB 6 DEC 72.
00300 CALL(GETFIL,[SIXBIT/TMP/],[SIXBIT/DATBGB/])↔POP0J
00400 CALL(SEGTV)
00500 INIT 1,17↔SIXBIT/DSK/↔0↔HALT
00600 LOOKUP 1,FILNAM↔GO[OUTSTR[ASCIZ/ LOOKUP FAILED.
00700 /]↔GO .+4]
00800 IN 1,DUMARG↔JFCL
00900 OUTSTR[ASCIZ" EOF.
01000 "]↔ RELEASE 1,
01100 POP0J
01200 DUMARG: IOWD 24400,HEADER↔0
01300 BEND;12/14/72-----------------------------------------------------
01400
01500 SUBR(TVDSKO)------------------------------------------------------
01600 BEGIN TVDSKO;INPUT TV PICTURE FROM A DISK FILE - BGB 6 DEC 72.
01700 CALL(GETFIL,[SIXBIT/TMP/],[SIXBIT/DATBGB/])↔POP0J
01800 CALL(SEGTV)
01900 INIT 1,17↔SIXBIT/DSK/↔0↔HALT
02000 ENTER 1,FILNAM↔GO[OUTSTR[ASCIZ/ ENTER FAILED.
02100 /]↔GO .+4]
02200 OUT 1,DUMARG↔JFCL
02300 OUTSTR[ASCIZ" EOF.
02400 "]↔ RELEASE 1,
02500 POP0J
02600 DUMARG: IOWD 24400,HEADER↔0
02700 BEND;12/14/72-----------------------------------------------------
00100
00200 SUBR(PLOTO)-------------------------------------------------------
00300 BEGIN PLOTO;DISPLAY BUFFER TO DISK FILE - BGB 10 DEC 1972.
00400 CALL(GETFIL,[SIXBIT/PLT/],[0])↔POP0J
00500 LAC 1,DPYBUF↔LACN(1)1↔SUBI 2
00600 CDR 2,(1)↔SETZM 1(2)
00700 MOVS↔LAPI -1(1)↔DAC DUMLST
00800 INIT 1,17↔SIXBIT/DSK/↔0↔HALT
00900 ENTER 1,FILNAM↔GO .+4
01000 OUT 1,DUMLST↔JFCL
01100 OUTSTR[ASCIZ" EOF.
01200 "]↔ RELEASE 1,
01300 POP0J
01400 DUMLST: 0↔0
01500 BEND;12/10/72------------------------------------------------------
00100 SUBR(TVXGP)-------------------------------------------------------
00200 BEGIN TVXGP; VIDEO BUFFER TO XEROX GRAPHICS PRINTER.
00300 ;BGB - 19 JANUARY 1973.
00400 ;ONE TO SIXTEEN EXPANSION: 216*4=864 BY (288*4=1152 OR 32 WORDS)
00500 ;XGP BUFFER SIZE 28513 = 864 LINES * 33 WORDS PER LINE + 1.
00600 ACCUMULATORS{S2,S3,I,J,K,Q,P1,P2}
00700
00800 ;EXPAND CORE FOR XGP BUFFER.
00900 LAC 44↔DAC SAV44#↔ADDI =28513↔IORI 1777
01000 CALLI 11↔GO L4↔CALL(SEGTV)
01100 CDR 1,SAV44↔SETZM(1)↔DIP 1,1↔AOS 1↔CDR 2,44↔BLT 1,(2)
01200
01300 ;PUT CONTROL WORD IN EACH ROW.
01400 LAC[1B11+=192B23+=32]↔LAC 1,SAV44↔AOS 1↔LACI 2,=864
01500 DAC(1)↔ADDI 1,=33↔SOJG 2,.-2↔SLACI 577000↔DAC(1)
01600
01700 LAC P1,[POINT 6,TVBUF,-1]
01800 LAC P2,SAV44↔ADDI P2,2
01900 LACI I,=216
02000 L1: LACI J,=32
02100 L2: SETZB 0,1↔SETZB 2,3
02200 LACI K,=9
02300 L3: ILDB Q,P1↔TRZ Q,3↔ROTC 0,4↔ROTC 2,4
02400 IOR 0,HTT+0(Q)↔IOR 1,HTT+1(Q)↔IOR 2,HTT+2(Q)↔IOR 3,HTT+3(Q)
02500 SOJG K,L3
02600 DAC 0,=00(P2)↔DAC 1,=33(P2)↔DAC 2,=66(P2)↔DAC 3,=99(P2)
02700 AOS P2
02800 SOJG J,L2
02900 ADDI P2,=100
03000 SOJG I,L1
03100
03200 DETSEG
03300 ;GRAB THE DEVICE.
03400 INIT 1,17↔SIXBIT/XGP/↔0↔GO[OUTSTR[
03500 ASCIZ/ CAN'T INIT XGP.
03600 /]↔ POP0J]
03700 LAC SAV44↔DAP DUMARG↔DAP DUMARG+1↔DAP DUMARG+2
03800 OUT 1,DUMARG↔RELEASE 1,
03900 LAC SAV44↔CALLI 11
04000 L4: OUTSTR[ASCIZ/ NOT ENUF CORE FOR XGP BUFFER.
04100 /]↔ CRLF↔POP0J
04200 DUMARG: XWD -=28513,0
04300 XWD -=28513,0
04400 XWD -=28513,0↔0
04500
00100 ;HALF TONE TABLE.
00200 HTT:
00300 00↔17↔17↔00 ; 2 LINES HORIZONTAL TOGETHER. 0
00400 00↔17↔00↔17 ; 2 LINES HORIZONTAL 1
00500 06↔06↔06↔06 ; 2 LINES VERTICAL TOGETHER 2
00600 00↔07↔07↔07 ; 9 DOTS TOGETHER 3
00700
00800 11↔06↔06↔11 ; BOTH DIAGONAL 4
00900 00↔17↔07↔00 ; 8 DOTS TOGETHER 5
01000 00↔00↔07↔07 ; 6 DOTS TOGETHER 6
01100 00↔06↔06↔00 ; 4 DOTS TOGETHER 7
01200
01300 17↔00↔00↔00 ; 1 LINE HORIZONTAL 10
01400 10↔10↔10↔10 ; 1 LINE VERTICAL 11
01500 10↔04↔02↔01 ; 1 LINE DIAGONAL 12
01600 00↔07↔00↔00 ; 3 DOTS TOGETHER 13
01700
01800 00↔03↔00↔00 ; 2 DOTS TOGETHER 14
01900 00↔01↔00↔40 ; 2 DOTS APART 15
02000 00↔01↔00↔00 ; 1 DOT 16
02100 00↔00↔00↔00 ; NOTHING. 17
02200
02300 BEND;1/19/73-------------------------------------------------------
00100 SUBR(CREOUT)------------------------------------------------------
00200 BEGIN CREOUT; CONTOUR,REGION,EDGE FILE FORMAT OUTPUT.
00300 ;BGB - 6 DECEMBER 1972.
00400
00500 SKIPN CTRL↔GO TVDSKO
00600
00700 CALL(GETFIL,[SIXBIT/CRE/],[0])↔POP0J
00800 LACN FILM
00900 CALL(RELLOC,0)
01000
01100 ;SETUP DUMP OUT ARGUMENT IOWD.
01200 LAC FILM↔SUB@AVAIL
01300 LACM 1,0↔MOVSS
01400 LAP OLD44↔DAC OUTARG
01500 LAC@FILM↔DAC TMP#↔DAC 1,@FILM ;FILE SIZE IN WORDS.
01600
01700 ;FILE OUTPUT RITUAL.
01710 LAC@AVAIL↔SUB FILM↔DAC@AVAIL
01800 INIT 1,17↔SIXBIT/DSK/↔0↔HALT
01900 ENTER 1,FILNAM
02000 GO[OUTSTR[ASCIZ/ ENTER FAILED.
02100 /]↔GO .+4]
02200 OUT 1,OUTARG↔JFCL
02300 OUTSTR[ASCIZ" EOF.
02400 "]↔ RELEASE 1,
02500 SETZM FILNAM↔SETZ EXTION↔SETZM EXTION+1↔SETZM PPPN
02600 CALL(RELLOC,FILM)
02700 LAC TMP↔DAC@FILM
02710 LAC@AVAIL↔ADD FILM↔DAC@AVAIL
02800 POP0J
02900 OUTARG: 0↔0
03000 BEND;1/8/73-------------------------------------------------------
00100 SUBR(CREIN)-------------------------------------------------------
00200 BEGIN CREIN; CONTOUR,REGION,EDGE FILE FORMAT INPUT.
00300 ;BGB - 28 JANURAY 1973.
00400
00500 SKIPN CTRL↔GO TVDSKI
00600 CALL(GETFIL,[SIXBIT/CRE/],[0])↔POP0J
00700 INIT 1,17↔SIXBIT/DSK/↔0↔HALT
00800 LOOKUP 1,FILNAM
00900
01000 SETZM QBLK
01100 LAC PPPN↔LAP FILM↔SOS↔DAC INARG ;IOWD
01200
01300 MOVS PPPN↔MOVMS↔ADD FILM
01400 IORI 1777↔CAMG 44↔GO L1
01500 CALLI 11↔HALT
01600 LAC 44↔AOS↔SUB FILM↔DIVI 7↔DAC 1,REMAINDER
01700 L1: IN 1,INARG
01800 RELEASE 1,
01900 OUTSTR[ASCIZ" EOF.
02000 "]↔ RELEASE 1,
02100 SETZM FILNAM↔SETZM EXTION↔SETZM EXTION+1↔SETZM PPPN
02110
02200 CDR@AVAIL↔ADD FILM↔DAC@AVAIL↔SETZM@
02300 DIP↔AOS↔LAC 1,44↔BLT(1) ;CLEAR EMPTY AREA.
02400 CALL(RELLOC,FILM)
02410
02420 ;RESET AVAIL LIST.
02500 LAC 1,@AVAIL↔LAC 2,44
02600 LIPI 1,NODSIZ(1)↔GO L6
02700 L5: HLRZM 1,(1)↔ADD 1,[XWD NODSIZ,NODSIZ]
02800 L6: CAILE 2,NODSIZ+NODSIZ-1(1)↔GO L5
02900 SUBI 2,NODSIZ-1(1)↔DAC 2,REMAINDER
03000
03200 CALL(DPYIMG)
03300 POP0J
03400 INARG: 0↔0
03500 BEND;1/28/73------------------------------------------------------
00100 SUBR(RELLOC)BASE--------------------------------------------------
00200 BEGIN RELLOC;RELOCATE ALL POINTERS - BGB - 6 DECEMBER 1972.
00300 ACCUMULATORS{A,B,C,D}
00400 DEFINE KAR(Q){CAR Q(A)↔SKIPE↔ADD B↔DIP Q(A)↔GO .+1}
00500 DEFINE KDR(Q){CDR Q(A)↔SKIPE↔ADD B↔DAP Q(A)↔GO .+1}
00600
00700 LAC B,ARG1 ;BASE ADDRESS.
00800 LAC A,FILM ;BLOCK POINTER.
00900
01000 L1: SKIPN(A)2↔GO[KDR 0↔GO L2] ;EMPTY BLOCK.
01100
01200 RELOC D,A↔TRNE D,400000↔LACI D,333333
01300 TRNE D,200000↔GO[KAR 0]↔ TRNE D,100000↔GO[KDR 0]
01400 TRNE D,20000 ↔GO[KAR 1]↔ TRNE D,10000 ↔GO[KDR 1]
01500 TRNE D,2000 ↔GO[KAR 3]↔ TRNE D,1000 ↔GO[KDR 3]
01600 TRNE D,200 ↔GO[KAR 4]↔ TRNE D,100 ↔GO[KDR 4]
01700 TRNE D,20 ↔GO[KAR 5]↔ TRNE D,10 ↔GO[KDR 5]
01800 TRNE D,2 ↔GO[KAR 6]↔ TRNE D,1 ↔GO[KDR 6]
01900
02000 L2: ADDI A,7+7↔CAML A,44↔POP1J
02100 SUBI A,7
02200 GO L1
02300 LIT
02400 BEND;12/20/72-----------------------------------------------------
00100 SUBR(TVIN4)------------------------------------------------------
00200 BEGIN TVIN4; FOUR BIT TELEVISION INPUT - BGB - 14 DEC 1972.
00300
00400 L0: INIT 17,17↔SIXBIT/TV/↔0
00500 GO[OUTSTR[ASCIZ"CAN'T INIT TV."]↔INCHRW↔GO .-3]
00600 SETZM TVERR↔INPUT 17,TVPTR↔RELEASE 17,
00700
00800 ;REPORT ON THE ERROR BITS AND RETAKE IF NECESSARY;
00900 LAC 1,TVERR
01000 TRNE 1,100000↔OUTSTR[ASCIZ/TV PARITY ERROR.
01100 /]↔ TRNE 1,40 ↔OUTSTR[ASCIZ/TV DATA MISS.
01200 /]↔ TRNE 1,20 ↔OUTSTR[ASCIZ/TV NON EX MEM.
01300 /]↔ TRNE 1,100060↔JRST L0
01400 CALLI 22↔DAC TVTIME#
01500 CALLI 14↔DAC TVDATE#
01600
01700 LAC[XWD HISTO,HISTO+1]↔SETZM HISTO↔BLT HISTO+77
01800 SETZM FTVSIX↔SETOM FTVHIS
01900
02000 ;CONVERT FROM GREY CODE TO GRAY CODE.
02100 LAC 16,[XWD L,0]↔BLT 16,12
02200 LAP TVPTR↔GO 4
02300
02400 L: POINT 4,0,-1↔ FROM←←0
02500 POINT 6,TVBUF,-1↔ TO←←1
02600 =62208 ↔ CNT←←2
02700 0 ↔ BYT←←3
02800 ILDB BYT,FROM ;4
02900 LAC BYT,GRAY(BYT) ;3
03000 LSH BYT,2 ;6
03100 AOS HISTO(BYT) ;7
03200 IDPB BYT,TO ;8
03300 SOJG CNT,4 ;9
03400 POP0J ;12
03500
03600 BEND;12/16/72-----------------------------------------------------
03700
03800 TVPTR: XWD -=6912,0
03900 TVCLIP: 701002 ;BCLIP=7 TCLIP=0 CAM=1.
04000 TVYXW: BYTE(9)50,34,40
04100 TVERR: 0
04200 GRAY: OCT 12,13,11,10,15,14,16,17,5,4,6,7,2,3,1,0
00100 SUBR(TVIN6)------------------------------------------------------
00200 BEGIN TVIN6; SIX BIT TELEVISION INPUT - BGB - 14 DEC 1972.
00300
00400 L0: INIT 17,17↔SIXBIT/TV/↔0
00500 GO[OUTSTR[ASCIZ"CAN'T INIT TV."]↔INCHRW↔GO .-3]
00600 SETZM TVERR6#↔PUSH P,TVCLIP
00700 LACI 76↔DPB[POINT 6,TVCLIP,23]
00800 LAC TVPTR↔LIPI 440400↔DAC P1#
00900 L1: SETZM TVERR↔INPUT 17,TVPTR↔LAC TVERR
01000 IORM TVERR6↔TRNE 100060↔GO L1
01100 LACI 54↔DPB[POINT 6,TVCLIP,23]
01200 LACI =6912↔ADDB TVPTR↔LIPI 440400↔DAC P2#
01300 L2: SETZM TVERR↔INPUT 17,TVPTR↔LAC TVERR
01400 IORM TVERR6↔TRNE 100060↔GO L2
01500 LACI 32↔DPB[POINT 6,TVCLIP,23]
01600 LACI =6912↔ADDB TVPTR↔LIPI 440400↔DAC P3#
01700 L3: SETZM TVERR↔INPUT 17,TVPTR↔LAC TVERR
01800 IORM TVERR6↔TRNE 100060↔GO L3
01900 LACI 10↔DPB[POINT 6,TVCLIP,23]
02000 LACI =6912↔ADDB TVPTR↔LIPI 440400↔DAC P4#
02100 L4: SETZM TVERR↔INPUT 17,TVPTR↔LAC TVERR
02200 IORM TVERR6↔TRNE 100060↔GO L4
02300 POP P,TVCLIP
02400
02500 ;REPORT ON THE ERROR BITS.
02600 LAC 1,TVERR6
02700 TRNE 1,100000↔OUTSTR[ASCIZ/TV PARITY ERROR.
02800 /]↔ TRNE 1,40 ↔OUTSTR[ASCIZ/TV DATA MISS.
02900 /]↔ TRNE 1,20 ↔OUTSTR[ASCIZ/TV NON EX MEM.
03000 /]
03100 CALLI 22↔DAC TVTIME#
03200 CALLI 14↔DAC TVDATE#
03300
03400 LAC[XWD HISTO,HISTO+1]↔SETZM HISTO↔BLT HISTO+77
03500 SETOM FTVSIX↔SETOM FTVHIS↔AOS(P);SKIP !!
03600
03700 ;CONVERT FROM GREY CODE TO GRAY CODE.
03800 LAC[POINT 6,TVBUF,-1]↔DAC P5#
03900 LAC[XWD L,3]↔BLT 16↔LACI =62208
04000 GO 3
04100
04200 ;SIX BIT AC-LOOP.
04300 L: ILDB 1,P1↔LAC 2,GRAY(1)
04400 ILDB 1,P2↔ADD 2,GRAY(1)
04500 ILDB 1,P3↔ADD 2,GRAY(1)
04600 ILDB 1,P4↔ADD 2,GRAY(1)
04700 IDPB 2,P5↔AOS HISTO(2)
04800 SOJG 0,3↔POP0J
04900
05000 BEND;12/16/72-----------------------------------------------------
00100 SUBR(TVCAMI)------------------------------------------------------
00200 BEGIN TVCAMI;TELEVISION CAMERA INPUT - BGB - 14 DEC 1972.
00300 CALL(LOCKIN)
00400 LAC 44↔DAC TMP44#↔AOS↔DAP TVPTR
00500 ADDI =6912↔SKIPE CTRL↔ADDI 3*=6912
00600 CALLI 11↔GO[FATAL(NO CORE FOR TVTAKE.)]
00700 CALL(SEGTV)
00800 LAC[XWD TVBUF,TVBUF+1]
00900 SETZM TVBUF↔BLT TVBUF+=10367
01000 SKIPE CTRL↔CALL(TVIN6)↔CALL(TVIN4)
01100 LAC TMP44↔CALLI 11↔JFCL
01200 CRLF↔UNLOCK↔POP0J
01300 BEND;12/16/72-----------------------------------------------------
00100 SUBR(CART)--------------------------------------------------------
00200 BEGIN CART
00300 OPDEF RADIO[7702B11]
00400 OPDEF HALTSW[043000636367]
00500 LAC 2,CHR ;INITIAL COMMAND CHARACTER.
00600 CAIN 2,"V"↔GO L0
00700 SKIPE CTRL↔TRO 2,200↔SKIPA ;SHIT.
00800 M0: INCHRW 2 ;WAIT FOR COMMAND CHARACTER.
00900 SETZM CNT0↔SETZM CNT1 ;ZIP TIME OF ANY PREVIOUS COMMAND.
01000 SETZM CTRL↔TRZE 2,200↔SETOM CTRL
01100 DAC 2,CHR
01200 SLACI 0,=20 ;ONE-THIRD OF A SECOND.
01300
01400 ;DRIVE ONE MINUTE FORWARDS OR BACKWARDS.
01500 CAIN 2,"F"↔GO[LAC 1,[XWD =3600,12]↔GO M1]
01600 CAIN 2,"B"↔GO[LAC 1,[XWD =3600,12]↔LAPI 0,2↔GO M1]
01700 SKIPE CTRL↔GO .+5
01800
01900 ;STEERING 5 SECONDS LEFT OR RIGHT.
02000 CAIN 2,"L"↔GO[LAC 1,[XWD =300,11]↔LAPI 1↔GO M1]
02100 CAIN 2,"R"↔GO[LAC 1,[XWD =300,11]↔LAPI 0↔GO M1]
02200
02300 ;CAMERA PAN 10 SECONDS LEFT OR RIGHT.
02400 CAIN 2,"L"↔GO[LAC 1,[XWD =600,14]↔GO M1]
02500 CAIN 2,"R"↔GO[LAC 1,[XWD =600,14]↔LAPI 0,4↔GO M1]
02600
02700 CAIN 2,"0"↔GO M0 ;HALT WITH SPACEWAR RUNNING.
02800 CAIN 2," "↔GO M0 ;HALT WITH SPACEWAR RUNNING.
02900 EX: SETZM FIREUP#↔HALTSW↔CRLF↔POP0J
03000
03100 M1: HLRZM 0,CNT0 ↔ DAPZ 0,WORD0
03200 HLRZM 1,CNT1 ↔ DAPZ 1,WORD1
03300
03400 ;FIREUP SPACE WAR MODULE.
03500 SKIPE FIREUP↔GO M0↔SETOM FIREUP
03600 LAC[XWD 200001,L4]↔CALLI $+3↔GO M0
03700
00100 ; FIRE UP SPACE WAR JOB.
00200 L0: SETZM CNT0↔SETZM CNT1
00300 LAC 1,[XWD 200001,L4]
00400 CALLI 1,400003
00500
00600 OUTCHR["*"]↔LACI 7↔DAC WORD2
00700 ;OLDE DIAGONOSTIC TTY LISTEN LOOP.
00800 L1: INCHRW↔CAIN "X"↔GO EX
00900 CAIGE"0"↔GO L2
01000 CAILE"8"↔GO L2
01100 ANDI 7↔DAC WORD2↔GO L1
01200 L2: CAIGE"A"↔GO L3
01300 CAILE"H"↔ANDI 7
01400 IORI 10↔DAC WORD2↔GO L1
01500 L3: CAIN 15↔OUTCHR["*"]↔GO L1
01600
01700 ; SPACE WAR OUTPUT TO RADIO TRANSMITTER.
01800
01900 L4: SOSLE CNT0↔GO[LAC WORD0↔GO L5]↔SETZM CNT0
02000 SOSLE CNT1↔GO[LAC WORD1↔GO L5]↔SETZM CNT1
02100 LAC WORD2
02200 L5: TRNE 8↔RADIO 400054; 1 SELECT ACTION RELAYS.
02300 TRNN 8↔RADIO 620054; 0 SELECT DIRECTION RELAYS.
02400 TRNE 1↔RADIO 440053; 1 STEERING MOTOR.
02500 TRNN 1↔RADIO 620053; 0 ;
02600 TRNE 2↔RADIO 410052; 1 DRIVE MOTOR.
02700 TRNN 2↔RADIO 600052; 0 ;
02800 TRNE 4↔RADIO 360051; 1 CAMERA PAN MOTOR.
02900 TRNN 4↔RADIO 570051; 0;
03000 RADIO 340050
03100 RADIO 340055
03200 CALLI 400024;EXIT SPACEWAR JOB.
03300 DECLARE{WORD0,WORD1,WORD2,CNT0,CNT1}
03400
03500 BEND;12/18/72-----------------------------------------------------
00100 SUBR(CAMERA)------------------------------------------------------
00200 BEGIN CAMERA
00300 OUTSTR[ASCIZ/ CAMERA = /]
00400 INCHRW
00500 ANDI 3
00600 LSH 9
00700 IORI 700002
00800 DAC TVCLIP
00900 CRLF
01000 POP0J
01100 BEND;12/6/72------------------------------------------------------